Traders.com

TRADESIGNAL: TREND, MOMENTUM, VOLATILITY, AND VOLUME (TMV)

The indicators discussed in “Trade Breakouts And Retracements With TMV” by Barbara Star in this issue can be used with our online charting tool at www.tradesignalonline.com. Check the Infopedia section for our Lexicon. There you will see the indicator and functions that you can make available for your personal account. Click on an indicator and select “Open script.” The indicator will immediately be available for you to apply on any chart. (See Figure 15.)

The source code is displayed below.

TradeSignalOnline source code for the "eKeltner Channel" indicator:
Meta:
	Synopsis("This original Keltner Channel was derived from Barbara Stars Article 'Trading with TMV' in the 02/2012 Issue of Technical Analysis of Stocks & Commodities"),
	Weblink("http://www.tradesignalonline.com/lexicon/view.aspx?id=Trade%20Breakouts%20and%20Retracements%20with%20TMV"),
	Subchart( False );

Inputs:
	Period( 20 ),
	Factor_ATR( 2.5 );

Vars:
	midLine, atrValue, upperLine, lowerLine;

midLine = XAverage( TypicalPrice, 20 );
atrValue = Average( TrueRAnge, 20 );
upperLine = midLine + atrValue * Factor_ATR;
lowerLine = midLine - atrValue * Factor_ATR;

DrawLine( midLine, "Mid Line", StyleDash, 1, Black );
DrawLine( upperLine, "Upper Line", StyleSolid, 1, Black );
DrawLine( lowerLine, "Lower Line", StyleSolid, 1, Black );



// *** Copyright tradesignal GmbH ***

// *** www.tradesignal.com ***

TradeSignalOnline source code for the "Volume Oscillator" indicator
Meta:
	Synopsis("This Indicator was derived from Barbara Stars Article 'Trading with TMV' in the 02/2012 Issue of Technical Analysis of Stocks & Commodities"),
	Weblink("http://www.tradesignalonline.com/lexicon/view.aspx?id=Trade%20Breakouts%20and%20Retracements%20with%20TMV"),
	Subchart( True );

Inputs:
	Fast_Period( 1 , 1 ),
	Slow_Period( 20 , 1 ),
	Peak_Level( 50 , 1 );
	

Vars:
	volValue, fastAvgValue, slowAVGValue;

fastAvgValue = AverageFC( Volume, Fast_Period );
slowAVGValue = AverageFC( Volume, Slow_Period );

volValue = ( ( fastAvgValue - slowAVGValue ) / ( fastAvgValue + slowAVGValue ) ) * 100;

If volValue > Peak_Level Then
	DrawForest( 0, volValue, "Zero", "Vol OSc", Thick, Black );

DrawLine( 0, "Baseline", StyleDash, 1, Black );



// *** Copyright tradesignal GmbH ***

// *** www.tradesignal.com ***

TradeSignalOnline source code for the "sKeltner Channel" indicator:
Meta:
	Synopsis("This Keltner Channel Variation was derived from Barbara Stars Article 'Trading with TMV' in the 02/2012 Issue of Technical Analysis of Stocks & Commodities"),
	Weblink("http://www.tradesignalonline.com/lexicon/view.aspx?id=Trade%20Breakouts%20and%20Retracements%20with%20TMV"),
	Subchart( False );

Inputs:
	Period( 20 );

Vars:
	midLine, atrValue, upperLine, lowerLine;

midLine = AverageFC( TypicalPrice, 20 );
atrValue = Average( Range, 20 );
upperLine = midLine + atrValue;
lowerLine = midLine - atrValue;

DrawLine( midLine, "Mid Line", StyleDash, 1, Black );
DrawLine( upperLine, "Upper Line", StyleSolid, 1, Black );
DrawLine( lowerLine, "Lower Line", StyleSolid, 1, Black );



// *** Copyright tradesignal GmbH ***

// *** www.tradesignal.com ***

TradeSignalOnline source code for the "ADX Color Bars":
Meta:
	Synopsis("This Indicator was derived from Barbara Stars Article 'Trading with TMV' in the 02/2012 Issue of Technical Analysis of Stocks & Commodities"),
	Weblink("http://www.tradesignalonline.com/lexicon/view.aspx?id=Trade%20Breakouts%20and%20Retracements%20with%20TMV"),
	Subchart( False );

Inputs:
	ADX_Period( 10 , 1 ),
	SMA_Period( 8 , 1 ),
	Color_Bullish( DarkGreen ),
	Color_Bearish( Red ),
	Color_Neutral( White );

Vars:
	longCond, shortCond, barColor, adxValue, smaValue;

adxValue = ADX( ADX_Period );
smaValue = Average( Close, SMA_Period );

longCond = adxValue > adxValue[1] And Close > smaValue;
shortCond = adxValue < adxValue[1] And Close < smaValue;

barColor = Color_Neutral;

if longCond Then
	barColor = Color_Bullish
Else If shortCond Then
	barColor = Color_Bearish;

DrawCandleStick( Open, High, Low, Close, barColor, barColor, DarkGray );



// *** Copyright tradesignal GmbH ***

// *** www.tradesignal.com ***

FIGURE 15: TRADESIGNALONLINE.COM, KELTNER CHANNEL AND VOLUME OSCILLATOR. Here is an example chart from Tradesignal Online displaying the eKeltner channel and volume oscillator indicator on a daily chart of the S&P 500 index.

—Henning Blumenthal
Tradesignal GmbH
This email address is being protected from spambots. You need JavaScript enabled to view it.
www.TradesignalOnline.com, www.Tradesignal.com