TRADERS’ TIPS

January 2012

Here is this month’s selection of Traders’ Tips, contributed by various developers of technical analysis software to help readers more easily implement some of the strategies presented in this and other issues.

Other code appearing in articles in this issue is posted in the Subscriber Area of our website at https://technical.traders.com/sub/sublogin.asp. Login requires your last name and subscription number (from mailing label). Once logged in, scroll down to beneath the “Optimized trading systems” area until you see “Code from articles.” From there, code can be copied and pasted into the appropriate technical analysis program so that no retyping of code is required for subscribers.

You can copy these formulas and programs for easy use in your spreadsheet or analysis software. Simply “select” the desired text by highlighting as you would in any word processing program, then use your standard key command for copy or choose “copy” from the browser menu. The copied text can then be “pasted” into any open spreadsheet or other software by selecting an insertion point and executing a paste command. By toggling back and forth between an application window and the open web page, data can be transferred with ease.

This month’s tips include formulas and programs for:

TRADESTATION: REVERSING MACD
METASTOCK: REVERSING MACD
THINKORSWIM.COM: REVERSING MACD
eSIGNAL: REVERSING MACD
WEALTH-LAB: REVERSING MACD
NEUROSHELL TRADER: REVERSING MACD
AIQ: REVERSING MACD
TRADERSSTUDIO: REVERSING MACD
TRADINGSOLUTIONS: REVERSING MACD
TRADECISION: REVERSING MACD
NINJATRADER: REVERSING MACD
TRADESIGNAL: REVERSING MACD
UPDATA: REVERSING MACD
SHARESCOPE: REVERSING MACD
MICROSOFT EXCEL: REVERSING MACD
AMIBROKER: REVERSING MACD — DOUGH ARTICLE CODE

TRADESTATION: REVERSING MACD

In “Reversing MACD” by Johnny Dough in this issue, Dough describes the construction of two indicators: one for the price chart and another for the indicator panel.

The chart indicator is designed to plot prices on the next bar that will result in an MACD value equal to the value on the current bar and the price level that will result in an MACD value of zero on the next bar.

The second indicator plots MACD in the indicator panel beneath price.

Both indicators include multiple variations of the values that are plotted (see Dough’s article for the different variations).

Here, we present indicator code for both indicators (“_PMACD_Ind1” is for the subgraph with price data and “_PMACD_Ind2” is for a subgraph below price data), along with the supporting functions

The “PlotTemplate” input in each indicator is used to determine which plots are displayed (notes were added to the code to cross-reference the PlotTemplate number with the author’s plot names).

Also included is strategy code for illustration only. The strategy uses the MACD value and the upper and lower Bollinger Bands for entry and exit.

_PMACD_Ind1 (Indicator for Price Sub-Graph)
{ TASC January 2012 }
{ Reversing MACD by Johnny Dough }

inputs:
	PlotTemplate( 1 ), { 1 = PMACD, 2 = PMACD_HLC, 
	 3 = PMACD_BB, 4 = PMACD_MTF }
	PMACDPrice( Close ), { price used for PMACDeq }
	P_Fast( 12 ),
	P_Slow( 26 ),
	P_Signal( 9 ), { PMACDeq EMA Signal length } 
	PMACD_TF_Mult1( 5 ), { length multiplier for 
	 higher TF } 
	PMACD_TF_Mult2( 21 ), { length multiplier for 
	 higher TF }
	p_bbperiod( 10 ), { BB average length }
	p_bbwidth( 1 ), { BB # of standard deviation }
	Displace( -1 ) ; { plot displacement }
	
variables:
	PMACDeq( 0 ),
	PMACDeqSignal( 0 ),
	PMACDeq_TF1( 0 ),
	PMACDeq_TF2( 0 ),
	PMACDzero( 0 ),
	UpperBand( 0 ),
	LowerBand( 0 ) ;

PMACDzero = _PMACDzero( PMACDPrice, P_Fast, P_Slow ) ;

{ Plots }
if PlotTemplate <> 2 then
	begin
	PMACDeq = _PMACDeq( PMACDPrice, P_Fast, P_Slow ) ;
	Plot1[Displace]( PMACDeq, "PMACDeq" ) ;
	end ;
	
Plot2[Displace]( PMACDzero, "PMACDzero" ) ;

if PlotTemplate = 2 then
	begin
	Plot3( _PMACDeq( High, P_Fast, P_Slow ), 
	 "PMACD H" ) ;
	Plot4( _PMACDeq( Close, P_Fast, P_Slow ), 
	 "PMACD C" ) ;	
	Plot5( _PMACDeq( Low, P_Fast, P_Slow ), 
	 "PMACD L" ) ;
	end ;
	
if PlotTemplate = 1 then
	begin
	PMACDeqSignal = XAverage( PMACDeq, P_Signal ) ;
	Plot6[Displace]( PMACDeqSignal, "PMACDeqSig" ) ;
	end ;
	  
if PlotTemplate = 3 then
	begin
	UpperBand = BollingerBand( PMACDeq, p_bbperiod, 
 	 p_bbwidth ) ;  
	LowerBand = BollingerBand( PMACDeq, p_bbperiod, 
 	 -p_bbwidth ) ;
	Plot7[Displace]( UpperBand, "UpperBand" ) ;
	Plot8[Displace]( LowerBand, "LowerBand" ) ;
	end ;

if PlotTemplate = 4 then
	begin
	PMACDeq_TF1 = _PMACDeq( PMACDPrice, P_Fast * 
	 PMACD_TF_Mult1, P_Slow * PMACD_TF_Mult1 ) ;
	PMACDeq_TF2 = _PMACDeq( PMACDPrice, P_Fast * 
	 PMACD_TF_Mult2, P_Slow * PMACD_TF_Mult2 ) ;
	Plot9[Displace]( PMACDeq_TF1, "PMACDeqTF1" ) ;
	Plot10[Displace]( PMACDeq_TF2, "PMACDeqTF2" ) ;
	end ;

_PMACD_Ind2 (Indicator for Sub-Graph Below Price)

{ TASC January 2012 }
{ Reversing MACD by Johnny Dough }
{ This indicator is designed to be inserted below 
  Price }
	
inputs:
	PlotTemplate( 1 ), { 1 = MACD, 2 = MACD_HLC, 
	 3 = MACD_BB, 4 = MACD_MTF }
	Price( Close ),
	FastLength( 12 ), 
	SlowLength( 26 ), 
	MACDLength( 9 ),
	BBAvgLen( 10 ),
	BBStdDev( 1 ),
	MACD_TF_Mult1( 5 ),
	MACD_TF_Mult2( 21 ) ;

variables:
	NumDecimals( Log( PriceScale ) / Log( 10 ) ),
	MyMACD( 0 ),
	MyMACD_TF1( 0 ),
	MyMACD_TF2( 0 ), 
	MACDAvg( 0 ),
	MACDBBAvg( 0 ), 
	MACDDiff( 0 ),
	string String1( "" ),
	string String2( "" ),
	UpperBand( 0 ),
	LowerBand( 0 ) ;

if PlotTemplate <> 2 then
	begin
	MyMACD = MACD( Price, FastLength, SlowLength ) ;
	Plot1( MyMACD, "MACD" ) ;
	Plot12( MyMACD, "MACDDots" ) ;
	end ;
	
if PlotTemplate = 1 then
	begin
	MACDAvg = XAverage( MyMACD, MACDLength ) ;
	MACDDiff = MyMACD - MACDAvg ;
	
	Plot2( MACDAvg, "MACDAvg" ) ;
	Plot3( MACDDiff, "MACDDiff" ) ;
	end ;

if PlotTemplate = 1 or PlotTemplate = 4 then
	begin
	String1 = "Next_PMACDeq = " + NumToStr( _PMACDeq( 
	 Price, FastLength, SlowLength ), NumDecimals ) ;
	Plot13( String1 ) ;
	
	String2 = "Next_PMACDzero = " + 
	 NumToStr( _PMACDzero( Price, FastLength, 
	  SlowLength ), NumDecimals ) ;
	Plot14( String2 ) ;
	end ;
		
if PlotTemplate <> 1 then 
	Plot4( 0, "ZeroLine" ) ;

if PlotTemplate = 2 then
	begin
	Plot15( MACD( High, FastLength, SlowLength ),
 	 "MACD-H" ) ; 
	Plot16( MACD( Close, FastLength, SlowLength ),
	 "MACD-C" ) ; 
	Plot17( MACD( Low, FastLength, SlowLength ),
	 "MACD-L" ) ; 
	end ;

if PlotTemplate = 3 then
	begin
	MACDBBAvg = Average( MyMACD, BBAvgLen ) ;
	UpperBand = BollingerBand( MyMACD, BBAvgLen, 
	 BBStdDev ) ;
	LowerBand = BollingerBand( MyMACD, BBAvgLen, 
	 -BBStdDev ) ;
	
	Plot5( UpperBand, "UpperBand" ) ;
	Plot6( LowerBand, "LowerBand" ) ;
	Plot7( MACDBBAvg, "BB Avg" ) ;
	Plot8( UpperBand, "UBand" ) ; { for cross-hatch }
	Plot9( LowerBand, "LBand" ) ; { for cross-hatch }
	
	{ Color for Plots 1 & 12 }
	if MyMACD > MyMACD[1] then
		begin
		SetPlotColor[1]( 1, Green ) ;
		SetPlotColor( 12, Green ) ;
		end
	else 
		begin
		SetPlotColor[1]( 1, Red ) ;
		SetPlotColor( 12, Red ) ;
		end ;
	end ;

if PlotTemplate = 4 then
	begin
	MyMACD_TF1 = MACD( Price, FastLength * 
	 MACD_TF_Mult1, SlowLength * MACD_TF_Mult1 ) ;
	MyMACD_TF2 = MACD( Price, FastLength * 
	 MACD_TF_Mult2, SlowLength * MACD_TF_Mult2 ) ;
	Plot10( MyMACD_TF1, "MACD TF1" ) ;
	Plot11( MyMACD_TF2, "MACD TF2" ) ;	
	SetPlotColor( 1, Blue ) ;
	SetPlotColor( 12, Blue ) ;
	end ;
		
if MACDDiff > 0 then
	if MACDDiff > MACDDiff[1] then
		SetPlotColor( 3, Green )
	else
		SetPlotColor( 3, DarkGreen ) ;

if MACDDiff <= 0 then
	if MACDDiff < MACDDiff[1] then
		SetPlotColor( 3, Red )
	else
		SetPlotColor( 3, DarkRed ) ;



_PMACD_Strategy (Strategy)
{ TASC January 2012 }
{ Reversing MACD by Johnny Dough }

inputs:
	MACDPrice( Close ), { price used for PMACDeq }
	P_Fast( 12 ),
	P_Slow( 26 ),
	P_Signal( 9 ), { PMACDeq EMA Signal length } 
	p_bbperiod( 10 ), { BB average length }
	p_bbwidth( 1 ) ; { BB # of standard deviation }

variables:
	MyMACD( 0 ),
	UpperBand( 0 ),
	LowerBand( 0 ) ;

MyMACD = MACD( MACDPrice, P_Fast, P_Slow ) ;
UpperBand = BollingerBand( MyMACD, p_bbperiod, 
 p_bbwidth ) ;  
LowerBand = BollingerBand( MyMACD, p_bbperiod, 
 -p_bbwidth ) ;

{ Entry }
if MyMACD crosses above UpperBand then
	Buy ( "MACD BB LE" ) next bar market ;

if MyMACD crosses below LowerBand then
	SellShort ( "MACD BB SE" ) next bar market ;

{ Exits }
if MyMACD crosses below UpperBand then
	Sell ( "MACD BB LX" ) next bar market ;

if MyMACD crosses above LowerBand then
	BuyToCover ( "MACD BB SX" ) next bar market ;



_PMACDeq (Function)

{ TASC January 2012 }
{ Reversing MACD by Johnny Dough }
{ returns price where MACD is equal to previous bar 
  MACD }
	
inputs:
	Price( numericseries ),
	period_X( numericsimple ),
	period_Y( numericsimple ) ;

variables:
	alphaX( 0 ),
	alphaY( 0 ) ;
		
once
	begin
	alphaX = 2 / ( 1 + period_X ) ;
	alphaY = 2 / ( 1 + period_Y ) ;
	end ;
	
_PMACDeq = ( XAverage( Price, period_X ) * alphaX - 
 XAverage( Price, period_Y ) * alphaY ) / 
 ( alphaX - alphaY ) ;



_PMACDlevel (Function)
{ TASC January 2012 }
{ Reversing MACD by Johnny Dough }

inputs:
	level( numericsimple ),
	Price( numericseries ),
	period_X( numericsimple ),
	period_Y( numericsimple ) ;

variables:
	alphaX( 0 ),
	alphaY( 0 ),
	One_alphaX( 0 ),
	One_alphaY( 0 ) ;
		
once
	begin
	alphaX = 2 / ( 1 + period_X ) ;
	alphaY = 2 / ( 1 + period_Y ) ;
	One_alphaX = 1 - alphaX ;
	One_alphaY = 1 - alphaY ;
	end ;

_PMACDlevel = ( Level + XAverage( Price, period_Y ) * 
 One_alphaY - XAverage( Price, period_X )* One_alphaX )
 / ( alphaX - alphaY ) ;


_PMACDzero (Function)

{ TASC January 2012 }
{ Reversing MACD by Johnny Dough }

inputs:
	Price( numericseries ),
	period_X( numericsimple ),
	period_Y( numericsimple ) ;
	
_PMACDzero = _PMACDlevel( 0, Price, period_X, 
 period_Y ) ;

To download the EasyLanguage code for the indicator, first navigate to the EasyLanguage FAQs and Reference Posts Topic in the EasyLanguage Support Forum (https://www.tradestation.com/Discussions/Topic.aspx?Topic_ID=47452), scroll down and click on the link labeled “Traders’ Tips, TASC.” Then select the appropriate link for the month and year. The ELD filename is “_PMACD.ELD.”

A sample chart is shown in Figure 1.

FIGURE 1: TRADESTATION, REVERSING MACD. Here is a daily chart of the S&P 500 index ($SPX.X) along with the two indicators (PlotTemplate is set to “3” in both indicators) and the strategy code. A long entry occurs when the MACD value crosses above the UpperBand and a long exit occurs when the MACD value crosses below the UpperBand. A short entry occurs when the MACD value crosses below the LowerBand and a short exit occurs when the MACD value crosses above the LowerBand.

This article is for informational purposes. No type of trading or investment recommendation, advice, or strategy is being made, given, or in any manner provided by TradeStation Securities or its affiliates.

—Chris Imhof
TradeStation Securities, Inc.
A subsidiary of TradeStation Group, Inc.
www.TradeStation.com