TRADERS’ TIPS

November 2010

Here is this month’s selection of Traders’ Tips, contributed by various developers of technical analysis software to help readers more easily implement some of the strategies presented in this and other issues.

Other code appearing in articles in this issue is posted in the Subscriber Area of our website at https://technical.traders.com/sub/sublogin.asp. Login requires your last name and subscription number (from mailing label). Once logged in, scroll down to beneath the “Optimized trading systems” area until you see “Code from articles.” From there, code can be copied and pasted into the appropriate technical analysis program so that no retyping of code is required for subscribers.

You can copy these formulas and programs for easy use in your spreadsheet or analysis software. Simply “select” the desired text by highlighting as you would in any word processing program, then use your standard key command for copy or choose “copy” from the browser menu. The copied text can then be “pasted” into any open spreadsheet or other software by selecting an insertion point and executing a paste command. By toggling back and forth between an application window and the open web page, data can be transferred with ease.

This month’s tips include formulas and programs for:

TRADESTATION: ZERO-LAG EMA
WEALTH-LAB: ZERO-LAG STRATEGY
eSIGNAL: ZERO-LAG STRATEGY
AMIBROKER: ZERO-LAG STRATEGY
WORDEN BROTHERS STOCKFINDER: ZERO-LAG STRATEGY
NEUROSHELL TRADER: ZERO-LAG STRATEGY
TRADERSSTUDIO: ZERO-LAG EMA
AIQ: SPECIAL K
TRADECISION: ZERO-LAG STRATEGY
NINJATRADER: ZERO-LAG STRATEGY
NEOTICKER: ZERO-LAG STRATEGY
WAVE59: ZERO-LAG STRATEGY
SHARESCOPE: ZERO-LAG STUDY
UPDATA: ZERO-LAG INDICATOR AND SYSTEM
VT TRADER: ZERO-LAG INDICATOR
EASYLANGUAGE CODE: ZERO-LAG INDICATOR —
EHLERS AND WAY ARTICLE CODE
TRADESIGNAL: ZERO-LAG INDICATOR

Return to Contents

TRADESTATION: ZERO-LAG EMA

In “Zero Lag (Well, Almost)” in this issue, authors John Ehlers and Ric Way present their zero-lag indicator and strategy.

We have adapted their zero-lag Ema by extending the functionality in an additional chart indicator named “ZeroLagEMAInd2” (see following code). An alert was added so that the user can be alerted when a crossing of the averages occurs, and a ShowMe dot can be plotted on the detection of a crossing. In addition, PaintBar functionality was added in the same indicator to paint the bars depending on which average (EC or Ema) is larger. The moving average plots, ShowMe dots, and PaintBars can all be toggled on and off via the inputs of the indicator. More notes can be found in the code.

To download the EasyLanguage code for ZeroLagEMAInd2 and the original zero-lag Ema indicator and strategy, go to the TradeStation and EasyLanguage Support Forum (https://www.tradestation.com/Discussions/forum.aspx??Forum_ID=213) and search for the file “Ehlers_ZeroLagEMA.eld.”

A sample chart is shown in Figure 1.

Figure 1: TRADESTATION, ZERO-LAG EMA. Shown here is a daily bar chart of Microsoft displaying the indicator “ZeroLagEMAInd2” (with all plots turned on). The yellow line is the EC average (EMA corrected with the gain). The red line is the EMA. The yellow and magenta dots are for the crossing of the moving averages, including the threshold requirement described by John Ehlers and Ric Way in their article. Finally, the bars are painted cyan when the EC is above the EMA, and red when the EC is below the EMA.

This article is for informational purposes. No type of trading or investment recommendation, advice, or strategy is being made, given, or in any manner provided by TradeStation Securities or its affiliates.

ZeroLagEMAInd2

inputs:
	Length( 20 ),
	GainLimit( 50 ),
	Thresh( 1 ), { see article for threshold explanation }
	UseThreshold( true ), { if true, then the threshold is used for the 
        ShowMe dots and crossing alert - see notes below } 
	DrawMALines( true ), { if true, the Moving Average lines are plotted }
	DrawShowMeDots( false ), { if true, ShowMe dots are plotted when a cross 
        of EC and EMA are detected }
	DotOffsetTicks( 10 ), { offset for the ShowMe dots }
	DrawPaintBars( false ) ; { draw PaintBars, color depending on EC > EMA }

variables:
	ATick( 0 ),
	alpha( 0 ),
	Gain( 0 ),
	BestGain( 0 ),
	EC( 0 ),
	Error( 0 ),
	LeastError( 0 ),
	EMA( 0 ),
	CrossOver( false ),
	CrossUnder( false ) ;

if CurrentBar = 1 then
	ATick = MinMove / PriceScale ; { calculate value of a tick }

alpha = 2 / ( Length + 1 ) ;
EMA = alpha * Close + ( 1 - alpha ) * EMA[1] ;
LeastError = 1000000 ;

for Value1 = -GainLimit to GainLimit 
	begin
	Gain = Value1 / 10 ;
	EC = alpha *( EMA + Gain * ( Close - EC[1] ) ) + ( 1 - alpha ) * EC[1] ;
	Error = Close - EC ;
	If AbsValue( Error ) < LeastError then 
		begin
		LeastError = AbsValue( Error ) ;
		BestGain = Gain ;
		end ;
	end ;

EC = alpha * ( EMA + BestGain * ( Close - EC[1] ) ) + ( 1 - alpha ) * EC[1] ;

if DrawMALines then
	begin
	Plot1( EC, "EC" ) ;
	Plot2( EMA, "EMA" ) ;
	end ;

{
The requirements for crosses over or under of EC in relation to EMA is 
dependent upon the "UseThreshold" input.  If the input is set to "True", 
the Threshold requirement is taken into account, similar to the strategy 
code posted by John Ehlers. Note that the CrossOver and CrossUnder variables 
not only control the plotting of the ShowMe dots but also the triggering of the alert.
}
CrossOver = IffLogic( UseThreshold, EC crosses over EMA and 
 100 * LeastError / Close > Thresh, EC crosses over EMA ) ;

CrossUnder = IffLogic( UseThreshold, EC crosses under EMA and 
 100 * LeastError / Close > Thresh, EC crosses under EMA ) ;

if CrossOver then
	begin
	if DrawShowMeDots then
		Plot3( Low - ATick * DotOffsetTicks, "ECxEMA", Yellow ) ;
	Alert( "EC cross over EMA" ) ; { alert for cross over }
	end ;
if CrossUnder then
	begin 
	if DrawShowMeDots then
		Plot3( High + ATick * DotOffsetTicks, "ECxEMA", Magenta ) ;
	Alert( "EC cross under EMA" ) ; { alert for cross under }
	end ;

{
This code emulates the PaintBar study.  If EC is above EMA, the bars are painted cyan,
 otherwise they are painted red.  Note that the plot styles has specific settings to 
 paint the bars properly.  If indicator is applied to a candlestick chart, the thickness 
 of the plots may need to adjusted. 
}	
If DrawPaintBars then
	begin
	Plot4( High ) ;
	Plot5( Low ) ;
	Plot6( Open ) ;
	Plot7( Close ) ;
	if EC > EMA then 
		begin
		SetPlotColor( 4, Cyan ) ;
		SetPlotColor( 5, Cyan ) ;
		SetPlotColor( 6, Cyan ) ;
		SetPlotColor( 7, Cyan ) ;
		end
	else
		begin
		SetPlotColor( 4, Red ) ;
		SetPlotColor( 5, Red ) ;
		SetPlotColor( 6, Red ) ;
		SetPlotColor( 7, Red ) ;
		end
	end ;

;

—Chris Imhof
TradeStation Securities, Inc.
A subsidiary of TradeStation Group, Inc.
www.TradeStation.com